package main

import "core:mem/virtual"
import "core:time"
import "core:strings"
import "core:unicode/utf8"
import "core:math/rand"
import "core:fmt"
import "core:math"
import "core:mem"

main :: proc() {

	arena: virtual.Arena
	arena_err := virtual.arena_init_growing(&arena)
	assert(arena_err == .None)
	arena_allocator := virtual.arena_allocator(&arena)

	context.allocator = arena_allocator

	NUM_LETTERS :: 26
	NUM_COMBOS :: 4

	LETTERS :: "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  #assert(len(LETTERS) == NUM_LETTERS)

	total_number_of_combinations := int(math.pow_f32(NUM_LETTERS, NUM_COMBOS))
	fmt.println("Max Amount of combinations:", total_number_of_combinations)

	runes := utf8.string_to_runes(LETTERS)

	used_combos, err := make(map[string]bool, total_number_of_combinations)
	if err != .None {
		return 
	}

	guessing_start := time.now()
	guessing_attempts := 0

	for len(used_combos) < total_number_of_combinations {
		free_all(context.temp_allocator)
		guessing_attempts += 1

		builder := strings.builder_make(context.temp_allocator)
		for _ in 0..<NUM_COMBOS {
			pos := rand.int63_max(NUM_LETTERS)
			letter := runes[pos]
			strings.write_rune(&builder, letter)
		}
		code := strings.to_string(builder)
		assert(len(code) == NUM_COMBOS)

		ok := code in used_combos
		if !ok { // good path. unused means we can insert now
			insertable_code := strings.clone(code)
			used_combos[insertable_code] = true // set dummy to insert key, a hashmap needs a value. but the value is of no value to us
			remaining_combos := total_number_of_combinations - len(used_combos)

			// because printing to console is expensive, only enable for debug / informative
			// fmt.printfln("Code %s inserted. Amount of insertion attempts: %v . %v unoccupied Codes Remain of %v total possibilities.", insertable_code, guessing_attempts, remaining_combos, total_number_of_combinations )

			guessing_attempts = 0
		}

	}

	guessing_end := time.now()
	diff := time.diff(guessing_start, guessing_end)
	dur_seconds := time.duration_seconds(diff)

	fmt.println("Took", dur_seconds, "seconds.")
}